DB Access Class Library for COBOL V1.0 API Reference - Microsoft(R) Windows(R) - - Microsoft(R) Windows NT(R) - - Microsoft(R) Windows(R) 2000 -

Contents Index

Chapter 10 Sample Codings Using Methods Provided

10.2 Sample Codings Using the GET-EDIT-MODE and IS-BOF Methods

Reference the current status of edit to the current row in a recordset.

 IDENTIFICATION   DIVISION.
 PROGRAM-ID. EDITMODE-APL.
 ENVIRONMENT DIVISION.
 CONFIGURATION    SECTION.
 
*Specify the class names that are used in the program.
 REPOSITORY.
     CLASS FJDB-SESSION
     CLASS FJDB-DATABASE
     CLASS FJDB-RECORDSET
     CLASS FJDB-ERROR.
 
*Specify the symbolic constants library used in the program.
 SPECIAL-NAMES.
     SYMBOLIC CONSTANT
     COPY FJDBOPT.
     .
 DATA DIVISION.
 WORKING-STORAGE SECTION.
 
*Define object variables.
 01 SESSION-A USAGE OBJECT REFERENCE FJDB-SESSION.
 01 DATABASE-A USAGE OBJECT REFERENCE FJDB-DATABASE.
 01 RECORDSET-A USAGE OBJECT REFERENCE FJDB-RECORDSET.
 01 ERROR-A USAGE OBJECT REFERENCE FJDB-ERROR.
 
*Define data setup variables.
 01 DSN   PIC X(100).
 01 UID   PIC X(100).
 01 PWD   PIC X(100).
 01 SCM   PIC X(100).
 01 OPT   PIC S9(9) COMP-5.
 01 SQL   PIC X(100).
 01 RSOPT PIC S9(9) COMP-5.
  
*Define a data return variable.
 01 EDT-MODE PIC S9(9) COMP-5.
 
*Define error information return variables.
 01 ERROR-COUNT   PIC S9(9) COMP-5.
 01 ERROR-MESSAGE PIC X(100).
 01 SQLSTATE      PIC X(5).
 01 SQLSTATE-SIZE PIC S9(9) COMP-5.
 01 MESSAGE-SIZE  PIC S9(9) COMP-5.
 
*Define a return value variable.
 01 RET-CODE PIC S9(9) COMP-5.
  
 PROCEDURE DIVISION.
 
*Describe an error handling procedure.
 DECLARATIVES.
 ERR SECTION.
     USE AFTER EXCEPTION FJDB-ERROR.
     INVOKE EXCEPTION-OBJECT "GET-COUNT" RETURNING ERROR-COUNT. 
     PERFORM  ERROR-COUNT TIMES
         INVOKE EXCEPTION-OBJECT "GET-SQLSTATE" 
                                   USING SQLSTATE SQLSTATE-SIZE
                                   RETURNING RET-CODE
         INVOKE EXCEPTION-OBJECT "GET-MESSAGE" 
                                   USING ERROR-MESSAGE MESSAGE-SIZE
                                   RETURNING RET-CODE
          DISPLAY "SQL-STATE= " SQLSTATE
          DISPLAY "MESSAGE=" ERROR-MESSAGE
          INVOKE EXCEPTION-OBJECT "GET-NEXT" RETURNING RET-CODE
     END-PERFORM.
     GO TO ERREND.
 END DECLARATIVES.
 
*Create an FJDB-SESSION class object.
     INVOKE FJDB-SESSION "CREATE-OBJECT" USING ERROR-A
                                          RETURNING SESSION-A.
 
*Set the values of arguments accompanying the OPEN-DATABASE method.
     MOVE "DB01" TO DSN.
     MOVE "YODA" TO UID.
     MOVE "YODA" TO PWD.
     MOVE "GENERAL" TO SCM.
     MOVE  FJDB-SCDBOPT-DEFAULT TO OPT.
 
*Connect to the database.
     INVOKE  SESSION-A "OPEN-DATABASE" 
                         USING DSN UID PWD SCM OPT DATABASE-A
                         RETURNING RET-CODE.
 
*Set the values of arguments accompanying the OPEN-RECORDSET method.
     MOVE "SELECT NO,NAME,ADDRESS FROM EMPLOYEE" TO SQL.
     MOVE FJDB-SCRSOPT-DEFAULT TO RSOPT.
 
*Create a recordset.
     INVOKE DATABASE-A "OPEN-RECORDSET" USING SQL RSOPT RECORDSET-A
                                             RETURNING RET-CODE.
 
*Reference the position of the current row in the recordset.
     IF RECORDSET-A::"IS-BOF" NOT = 0 THEN
         DISPLAY "BOF"
     END-IF.
     IF RECORDSET-A::"IS-EOF" NOT = 0 THEN
         DISPLAY "EOF"
     END-IF.
 
*Reference the status of edit to the current row.
     INVOKE RECORDSET-A "GET-EDIT-MODE" RETURNING EDT-MODE.
     DISPLAY "EDIT-MODE=" EDT-MODE.
 
 ERREND.
 
*Collect the objects.
     SET RECORDSET-A TO NULL.
     SET DATABASE-A TO NULL.
     SET SESSION-A TO NULL.
     SET ERROR-A TO NULL.
 END PROGRAM EDITMODE-APL.

Contents Index