DB Access Class Library for COBOL V1.0 API Reference - Microsoft(R) Windows(R) - - Microsoft(R) Windows NT(R) - - Microsoft(R) Windows(R) 2000 -

Contents Index

Chapter 10 Sample Codings Using Methods Provided

10.4 Sample Codings Using the BEGIN-TRAN,COMMIT-TRAN,ROLLBACK-TRAN Methods

Execute a procedure for cutting inventories in an inventory table and increasing deliveries in a delivery table, both kept on a database, in the same transaction. If the procedure for increasing deliveries fails, the procedure for cutting inventories is canceled as well.

 IDENTIFICATION DIVISION.
 PROGRAM-ID. TRAN-APL.
 ENVIRONMENT DIVISION.
 CONFIGURATION SECTION.
 
*Specify the class names that are used in the program.
 REPOSITORY.
     CLASS FJDB-SESSION
     CLASS FJDB-DATABASE
     CLASS FJDB-ERROR.
 
*Specify the symbolic constants library used in the program.
 SPECIAL-NAMES.
     SYMBOLIC CONSTANT
     COPY FJDBOPT.
     .
 
 DATA DIVISION.
 WORKING-STORAGE SECTION.
 
*Define object variables.
 01 SESSION-A USAGE OBJECT REFERENCE FJDB-SESSION.
 01 DATABASE-A USAGE OBJECT REFERENCE FJDB-DATABASE.
 01 ERROR-A USAGE OBJECT REFERENCE FJDB-ERROR.
 
*Define data setup variables.
 01 DSN   PIC X(100).
 01 UID   PIC X(100).
 01 PWD   PIC X(100).
 01 SCM   PIC X(100).
 01 OPT   PIC S9(9) COMP-5.
 01 N-SQL PIC X(100).
 01 Z-SQL PIC X(100).
 
*Define a data return variable.
 01 ROW-COUNT PIC S9(9) COMP-5.
 
*Define error information return variables.
 01 ERROR-COUNT   PIC S9(9) COMP-5.
 01 ERROR-MESSAGE PIC X(100).
 01 SQLSTATE      PIC X(5).
 01 SQLSTATE-SIZE PIC S9(9) COMP-5.
 01 MESSAGE-SIZE  PIC S9(9) COMP-5.
 
*Define return value variables.
 01 RET-CODE      PIC S9(9) COMP-5.
 01 W-RET-CODE    PIC S9(9) COMP-5.
 
 PROCEDURE DIVISION.
 
*Describe an error handling procedure.
 DECLARATIVES.
 ERR SECTION.
     USE AFTER EXCEPTION FJDB-ERROR.
     INVOKE EXCEPTION-OBJECT "GET-COUNT" RETURNING ERROR-COUNT. 
     PERFORM  ERROR-COUNT TIMES
         INVOKE EXCEPTION-OBJECT "GET-SQLSTATE" 
                                  USING SQLSTATE SQLSTATE-SIZE
                                  RETURNING W-RET-CODE
         INVOKE EXCEPTION-OBJECT "GET-MESSAGE" 
                                  USING ERROR-MESSAGE MESSAGE-SIZE
                                  RETURNING W-RET-CODE
         DISPLAY "SQL-STATE= " SQLSTATE
         DISPLAY "MESSAGE=" ERROR-MESSAGE
         INVOKE EXCEPTION-OBJECT "GET-NEXT" RETURNING W-RET-CODE
     END-PERFORM.
 END DECLARATIVES.
 
*Create an FJDB-SESSION class object.
     INVOKE FJDB-SESSION "CREATE-OBJECT" USING ERROR-A
                                         RETURNING SESSION-A.
     IF SESSION-A = NULL THEN
          GO TO TERMPROCESS
     END-IF.
 
*Set the values of arguments accompanying the OPEN-DATABASE method.
     MOVE "DB01"    TO DSN.
     MOVE "YODA"    TO UID.
     MOVE "YODA"    TO PWD.
     MOVE "GENERAL" TO SCM.
     MOVE  FJDB-SCDBOPT-DEFAULT TO OPT.
 
*Connect to the database.
     INVOKE  SESSION-A "OPEN-DATABASE" 
                        USING DSN UID PWD SCM OPT DATABASE-A
                        RETURNING RET-CODE.
     IF RET-CODE NOT = 0 THEN
          GO TO TERMPROCESS
     END-IF.
 
*Begin a transaction directed at the database.
     INVOKE DATABASE-A "BEGIN-TRAN" RETURNING RET-CODE.
     IF RET-CODE NOT = 0 THEN
          GO TO TERMPROCESS
     END-IF.
 
*Update the DELIVERY table.
     MOVE "UPDATE DELIVERYTBL SET DELIVERYCOUNT = DELIVERYCOUNT +1 WHERE ITEMCODE = 101" 
                                         TO N-SQL.
     INVOKE DATABASE-A "EXECUTE-SQL" USING N-SQL ROW-COUNT 
                                     RETURNING RET-CODE.
     IF RET-CODE NOT = 0 THEN
          INVOKE DATABASE-A "ROLLBACK-TRAN" RETURNING RET-CODE
          GO TO TERMPROCESS
     END-IF.
     DISPLAY "ROW-COUNTiDELIVERYTBLj=" ROW-COUNT.
 
*Update the INVENTORY table.
     MOVE "UPDATE INVENTORYTBL SET INVENTORYCOUNT = INVENTORYCOUNT-1 WHERE ITEMCODE = 101"
                                         TO Z-SQL.
     INVOKE DATABASE-A "EXECUTE-SQL" USING Z-SQL ROW-COUNT
                                     RETURNING RET-CODE.
     IF RET-CODE NOT = 0 THEN
          INVOKE DATABASE-A "ROLLBACK-TRAN" RETURNING RET-CODE
          GO TO TERMPROCESS
     END-IF.
     DISPLAY "ROW-COUNTiDELIVERYTBLj=" ROW-COUNT.
 
*End the transaction.
     INVOKE  DATABASE-A "COMMIT-TRAN" RETURNING RET-CODE.
 
 TERMPROCESS.
 
*Collect the objects.
     SET ERROR-A TO NULL.
     SET DATABASE-A TO NULL.
     SET SESSION-A TO NULL.
 END PROGRAM TRAN-APL.

Contents Index